Foglio di Calcolo

Indovina la parola

Descrizione del gioco

Il gioco consiste nel memorizzare un elenco di parole di 5 lettere.
Se ne estrae una a caso e la si tiene nascosta da parte.
Il solutore ha a disposizione un certo numero di tentativi (ad esempio 7) per tentare di indovinarla.
Ad ogni tentativo dello sfidante si mostra, per ogni lettera della parola proposta dal solutore, la lettera stessa se si trova nella posizione giusta oppure ‘No’ se non c’è.
Sulla base di queste indicazioni lo sfidante compie altri tentativi

---

la tabella delle parole segrete

1. Eliminare il foglio 3.

2. Cambiare il nome al foglio 2 in “Segreto”.

3. Nella cella A1 scrivere “Parola segreta”.

4. Nella cella A3 scrivere: "Elenco"

5. A iniziare dalla cella A4, scrivere 10 parole, di 5 lettere, tutte della stessa categoria, ad esempio 10 città, 10 animali, 10 nomi di persona, ecc...

6. Nella cella C2 scrivere un qualsiasi numero compreso tra 1 e 10.

7. Nella cella C1 scrivere la formula:

=INDICE(A4:A13;C2)

Questa formula richiede due parametri:

• l'intervallo di celle, o tabella, contenente un elenco di valori, in questo caso l'intervallo è composto dalle celle comprese tra la riga 4 e la riga 13 della colonna A

• la posizione (o indice), all'interno della tabella del valore da estrarre. In questo caso non viene specificato un valore, ma la cella che contiene il valore (C2).

L'intervallo viene indicato con le celle estreme separate dal carattere due punti.
I parametri della funzione sono separati tra loro dal carattere punto e virgola.
La cella contiene la formula (che viene mostrata nella barra della formula), ma nel foglio viene mostrato il risultato della formula. Nella figura a lato la funzione estrae dalla posizione 6 della tabella il valore Libro

---

Estrazione delle singole lettere che compongono la parola

8. Nell'intervallo D2:H2 scrivere la numerazione da 1 a 5. Questi numeri rappresenteranno la lettera da estrarre dalla parola.

la scomposizione della parola in lettere è necessaria perchè si dovranno confrontare le lettere della parola segreta con le singole lettere della parola proposta dal giocatore, al fine di comunicare l'esito del suo tentativo.

9. Nella cella D1 scrivere la formula:

=STRINGA.ESTRAI($C1;D2;1)

Questa formula richiede tre parametri:

• la cella contenente il testo da cui estrarre una o più lettere,

• la cella contenente la posizione della prima lettera da estrarre,

• il numero (o, eventualemente, la cella) contenente il numero di lettere da estrarre.

10. Copiare la formula scritta nella cella D1 nelle celle da E1 a H1.

Notare che, dopo la copia, è rimasto il riferimento alla cella C1.

"

---

schema del gioco.

1. Passare al Foglio 1.

2. Cambiare il nome al foglio in “Gioco”.

3. Nella cella A1 scrivere:

   Indovina in 7 tentativi (al massimo) una parola di 5 lettere.

4. Nella cella A2 scrivere:

   Scrivi le parole nelle celle della colonna A3:A9

5. Copiare l’intervallo D1:H2 del foglio “Segreto” nell’intervallo H3:L4 del foglio “Gioco”.

6. Mentre l'intervallo è ancora selezionato, notare che la formula fa riferimento alla cella C3, mentre il giocatore deve scrivere la sua parola nella cella A3. Nel menu Modifica, scegliere Sostituisci. Nella casella "Trova" scrivere $C e nella casella "Sostituisci con:" scrivere $A

7. Nella cella A3 scrivere la prima parola di cinque lettere, per iniziare il gioco.

8. Nella cella B3 del foglio “Gioco” scrivere la formula:

   =SE(H3=Segreto!D$1;H3;"No")
   questa formula effettua il confronto tra la lettera della parola inserita e la corrispondente lettera della parola da indovinare, se la lettera è uguale la mostra altrimenti scrive “No”.

9. Copiare questa formula nell’intervallo C3:F3.

---

inserire suggerimenti

Al di sotto di ogni risposta si può mostrare se la lettera scritta in quella posizione è comunque presente nella parola.
Le formule seguenti comunicano che la lettera nella posizione corrispondente è presente nella parola confrontandola con le restanti quattro.
il test nella funzione "SE" è ottenuto da una funzione OR basata su 4 confronti.
se ne mette in evidenza la struttura solo nella prima formula.

22. nella cella B4 scrivere la seguente formula:

    =SE(

      O(

          H$3=Segreto!E$1;

          H$3=Segreto!F$1;

          H$3=Segreto!G$1;

          H$3=Segreto!H$1

      );

      H$3 & " c'è";

      "")

23. nella cella C4 scrivere la seguente formula:

    =SE(O(I$3=Segreto!D$1;I$3=Segreto!F$1;I$3=Segreto!G$1;I$3=Segreto!H$1);I$3 & " c'è";"")

24. nella cella D4 scrivere la seguente formula:

    =SE(O(J$3=Segreto!D$1;J$3=Segreto!E$1;J$3=Segreto!G$1;J$3=Segreto!H$1);J$3 & " c'è";"")

25. nella cella E4 scrivere la seguente formula:

    =SE(O(K$3=Segreto!D$1;K$3=Segreto!E$1;K$3=Segreto!F$1;K$3=Segreto!H$1);K$3 & " c'è";"")

26. nella cella F4 scrivere la seguente formula:

    =SE(O(L$3=Segreto!D$1;L$3=Segreto!E$1;L$3=Segreto!F$1;L$3=Segreto!G$1);L$3 & " c'è";"")

---

Iniziare una nuova partita

27. Nella cella C3 del foglio "Segreto" scrivere la formula: =INT(CASUALE()*10+1).

28. Selezionare il foglio “Gioco”.

29. A seconda della versione di Excel, il comando Macro potrebbe essere disponibile nel menu Strumenti o nel menu Visualizza
    Individuato il comando Macro nell'appropriato menu, si apre un sottomenu: scegliere il comando Registra nuova macro
    Si apre un riquadro di dialogo,

    • dare il nome “AltraPartita”

    • assegnare un tasto di scelta rapida, ad esempio "p"

    • Ok

      Da questo momento qualsiasi operazione viene effettuata sarà registrata.

    • Selezionare la cella A3 del foglio "Gioco".

    • Premere il tasto ‘Cancella’.

    • Aprire il foglio “Segreto”.

    • Selezionare la cella C3.

    • Premere il pulsante Copia.

    • Selezionare la cella C2.

    • Aprire il menu Modifica scegliere il comando "Incolla Speciale" marcare la casella "Valori" e premere Ok. Premere il tasto Esc.

    • Passare al foglio “Gioco” e selezionare la cella A3.

    • Fermare il registratore di macro.

Provare il gioco. Quando si vuole iniziare una nuova partita basta premere la combinazione di tasti Ctrl+p.
La funzione CASUALE() viene richiamata ogni volta che si scrive un nuovo valore in una cella, quindi, per evitare che durante i tentativi del giocatore, il numero cambi e indichi quindi una parola diversa ad ogni tentativo, il numero generato viene copiato e incollato nella cella usata dalla funzione INDICE per accedere all'elenco delle parole segrete.
Come si vede, non si è imposto il limite dei 7 tentativi. In questa versione, il gioco, consente di scrivere le parole solo nella cella A3, cancellando le parole precedenti. Lo studente trovi un rimedio a questo inconveniente.

---

Esercizi proposti

I problemi seguenti richiedono una conoscenza avanzata della programmazione in Excel.

• Modificare il gioco in modo che, all’inizio di una nuova partita, compaia una lettera della parola da indovinare nella sua posizione.

• Se dopo l’ultimo tentativo ammesso non si è riusciti a indovinare la parola il programma deve rivelare quale era la parola segreta. Suggerimento: usare la funzione conta.valori per stabilire quando sono state provate 7 parole.